******************************************************
*                                                    *
*               INITIALISIEREN DES                   *
*               RHOTRON-BUSSES                       *
*               UND AUSLESEN VON DATUM UND           *
*               UHRZEIT                              *
*                                                    *
******************************************************
*                                                    *
*         MODULHEADER                                *
*                                                    *
       DC.L   0              ADR. OF NEXT HEADER
       DC.L   0              ADR. OF LAST HEADER
       DC     $0010          MODULINDIKATOR
       DC.B   'READCL'       MODULNAME
******************************************************
*                                                    *
*        HYPERPROZESSOR UND TRAP DEFINITIONS         *
*                                                    *
******************************************************
ENTR   OPD.V  29             OPCODE PROC-ENTRY
EPAR   OPD.V  19             END OF PARAMETER LIST
ARBS   OPD.V  123            UEBERGABE BIT-STRING
RETN   OPD    $4E4C          RETURN TRAP
OFF    OPD    $4E4F          DISPATCHER OFF
QDPC   OPD    $4E43          DISPATCHER ON
******************************************************
*                                                    *
*              PSW - ALLOCATION                      *
******************************************************
PAR1   EQU    0              POINTER AUF ARRAY
BOUND1 EQU    PAR1+4         FELDBESCHREIBUNGSBLOCK
OFFSET EQU    BOUND1+2
WSPZ   EQU    OFFSET+4       LAENGE PROZ. WORKSPACE
******************************************************
*              EQUATES FUER READCL                   *
******************************************************
FLIPFL EQU    $F00000        ADR. DEKODER-RAM FLIPFLOP
MUFUAD EQU    $B88000        ADR. UHRENBAUSTEIN
******************************************************
>READCL  ENTR   WSPZ.L       START PARAMETERUEBERNAHME
         ARBS   OFFSET.X,BOUND1.X,$0410.X
         EPAR                ENDE PARAMETER REELL
         LEA    MUFUAD,A1
         MOVE   =1,D1        SLOT 1 ANSPRECHEN
         OFF                 DISPATCHER ABSCHALTEN
         TST.B  FLIPFL       DEKODER FLIPFLOP
         MOVE.B D1,(A1)      BUSADRESSE DEFINIEREN
         ANDI   =$D8FF,SR    PRIVILEGIERTEN ZUSTAND AUFHEBEN
         QDPC                DISPATCHER ANSCHALTEN
         MOVE.W =$C,D1       ANZAHL AUSZULESENDER REGISTER
         CLR.W  D2
         MOVEA.L OFFSET(A5),A2 ANFANGSADRESSE DES FELDS
         TST.W  (A2)+          ZELLE 0 UEBERSPRINGEN
         LEA    MUFUAD+1,A1    ANFANGSADRESSE UHR
         MOVE.B =$00,(A1)      BETRIEBSART EINSTELLEN
         MOVE.B =$80,$C(A1)    SUB-MODUS EINSTELLEN
         ORI.B   =$40,$8(A1)   DATENRICHTUNG PORT C
         ANDI.B  =$BF,$18(A1)  UHRENCHIP SELEKTIEREN
LESEN:   MOVE.B =$FF,$4(A1)    DATENRICHTUNG PORT A
         MOVE.B D2,D0          REGISTERNUMMER
         AND.B  =$0F,D0
         MOVE.B D0,$10(A1)     REGISTER AUSWAEHLEN
         OR.B   =$80,D0        ADR.WRITE-IMPULS SETZEN
         MOVE.B D0,$10(A1)
         AND.B  =$0F,D0        ADR.WRITE-IMPULS RUECKSETZEN
         MOVE.B D0,$10(A1)
         MOVE.B =$F0,$4(A1)    DATENRICHTUNG PORT A
         MOVE.B =$40,$10(A1)   READ-IMPULS SETZEN
         MOVE.B $10(A1),D0     REGISTER AUSLESEN
         AND.W  =$000F,D0      BCD-WERT MASKIEREN
         MOVE.W  D0,(A2)+   WERT IN FELD ABLEGEN
         ADDQ   =$1,D2         NAECHSTES REGISTER
         DBF     D1,LESEN
         ANDI.B  =$BF,$8(A1)   UHR DESELKTIEREN
         ORI.B   =$40,$18(A1)
         RETN                ZURUECK INS HAUPTPR.
         END